Arbeitszeiterfassung in Excel: Formeln, Vorlage und Grenzen

Excel ist für viele Betriebe der erste Schritt weg vom Papier-Stundenzettel. Damit die Tabelle richtig rechnet, braucht es ein paar Formeln – für Arbeitszeiten über Mitternacht, Monatssummen über 24 Stunden, Überstunden, Pausen und Nachtarbeit. Hier finden Sie alle Formeln zum Kopieren, jeweils für Österreich und Deutschland, und eine kostenlose Vorlage, in der sie schon eingebaut sind.

Darf ich Arbeitszeiten in Excel erfassen?

Aufgezeichnet werden muss in beiden Ländern. Seit dem Urteil des Europäischen Gerichtshofs (C-55/18) brauchen Arbeitgeber ein System, das die tägliche Arbeitszeit objektiv und verlässlich festhält.

• Österreich: Nach § 26 AZG führt der Arbeitgeber Aufzeichnungen über die geleisteten Arbeitsstunden. Das AZG nennt keine eigene Aufbewahrungsfrist; für lohnrelevante Unterlagen gilt die steuerliche Frist von sieben Jahren (§ 132 BAO). Mehr dazu: Aufzeichnungspflicht nach § 26 AZG einfach erklärt
• Deutschland: Seit dem Beschluss des Bundesarbeitsgerichts vom 13.09.2022 (1 ABR 22/21) sind Beginn und Ende der täglichen Arbeitszeit zu erfassen. § 16 Abs. 2 ArbZG verlangt, Arbeitszeit über acht Stunden werktäglich aufzuzeichnen und zwei Jahre aufzubewahren; nach § 17 MiLoG gilt in bestimmten Branchen und für Minijobs: Beginn, Ende und Dauer spätestens nach sieben Tagen. Mehr dazu: Zeiterfassung Pflicht in Deutschland

Ein bestimmtes Format schreibt das Gesetz derzeit nicht vor. Entscheidend ist, dass die Aufzeichnung vollständig, zeitnah und nachvollziehbar ist – daran scheitern Excel-Tabellen in der Praxis am häufigsten (mehr dazu unten).

Dieser Beitrag beschreibt, wie Sie Arbeitszeiten in Excel berechnen. Er ersetzt keine Rechtsberatung.

So bauen Sie die Tabelle auf

Wichtig: Uhrzeiten mit Doppelpunkt eingeben (7:30), nicht als Dezimalzahl (7,5).

Die Formeln

Die Formeln sind für das deutschsprachige Excel geschrieben (Trennzeichen ;). Beispiel für Zeile 2.

1. Arbeitszeit netto – auch über Mitternacht

=WENN(UND(B2<>"";C2<>"");REST(C2-B2;1)-N(D2);"")

REST(…;1) sorgt dafür, dass eine Schicht von 22:00 bis 6:00 korrekt 8 Stunden ergibt statt einer negativen Zeit. N(D2) zählt eine leere Pausenzelle als 0.

2. Monatssumme über 24 Stunden

=SUMME(E2:E32)

Die Zelle als [h]:mm formatieren (Zellen formatieren → Benutzerdefiniert). Ohne die eckigen Klammern zeigt Excel nach 24 Stunden wieder bei 0 an – aus 51:55 Stunden würde 3:55.

3. Stunden als Dezimalzahl (für die Lohnverrechnung)

=RUNDEN(E2*24;2)

7:30 Stunden werden zu 7,5.

4. Über- und Minusstunden

Überstunden:

=MAX(0;E2-G2)

Minusstunden:

=MAX(0;G2-E2)

Ob Mehr- oder Überstunden vorliegen und welche Zuschläge gelten, regeln Gesetz, Kollektiv- bzw. Tarifvertrag und Arbeitsvertrag – die Formel rechnet nur die Differenz zur Sollzeit.

5. Pausen prüfen

Deutschland (§ 4 ArbZG): 30 Minuten bei mehr als 6 Stunden, 45 Minuten bei mehr als 9 Stunden

=WENN(E2>9/24;WENN(N(D2)<45/1440;"Pause zu kurz";"");WENN(E2>6/24;WENN(N(D2)<30/1440;"Pause zu kurz";"");""))

Österreich (§ 11 AZG): 30 Minuten bei mehr als 6 Stunden

=WENN(E2>6/24;WENN(N(D2)<30/1440;"Pause zu kurz";"");"")

Die Formel zeigt nur an, ob eine Pause fehlt. Ziehen Sie Pausen nicht automatisch ab – sie müssen tatsächlich genommen werden.

6. Höchstarbeitszeit

Deutschland (§ 3 ArbZG): höchstens 10 Stunden

=WENN(E2>10/24;"über 10 h";"")

Österreich (§ 9 AZG): höchstens 12 Stunden

=WENN(E2>12/24;"über 12 h";"")

7. Nachtstunden

Zuerst eine Hilfsspalte I für das Schichtende über Mitternacht:

=WENN(C2<B2;C2+1;C2)

Deutschland (Nachtzeit 23–6 Uhr, § 2 Abs. 3 ArbZG):

=RUNDEN((MAX(0;MIN(I2;30/24)-MAX(B2;23/24))+MAX(0;MIN(I2;6/24)-B2))*24;2)

Österreich (Nachtzeit 22–5 Uhr):

=RUNDEN((MAX(0;MIN(I2;29/24)-MAX(B2;22/24))+MAX(0;MIN(I2;5/24)-B2))*24;2)

Das Ergebnis sind Nachtstunden als Dezimalzahl, Pausen nicht abgezogen. In Bäckereien gilt in Deutschland 22–5 Uhr – dann die österreichische Formel verwenden.

Englisches Excel, Google Tabellen, Numbers: Die Funktionen heißen IF, AND, MOD, ROUND, SUM, und das Trennzeichen ist meist das Komma statt des Semikolons.

Kostenlose Vorlage mit fertigen Formeln

Sie müssen nichts selbst bauen: Unsere Vorlagen für Stundenzettel (Monat), Arbeitszeitnachweis (Woche) und Dienstplan (Woche) gibt es als Excel mit eingebauten Formeln und als PDF zum Ausdrucken – passend für Österreich und Deutschland.

Vorlagen kostenlos herunterladen →

Wo Excel an Grenzen stößt

Eine Excel-Tabelle rechnet richtig, solange die Eingaben stimmen. Genau dort liegen die Schwachstellen:

• Nachgetragen statt erfasst: Die Zeiten landen oft erst abends oder am Monatsende in der Tabelle, aus der Erinnerung. Zeitnah ist das nicht.
• Änderungen ohne Spur: Eine überschriebene Zelle zeigt nicht, wer wann was geändert hat.
• Nicht vor Ort: Wer auf der Baustelle, im Objekt oder beim Kunden arbeitet, hat die Tabelle nicht dabei.
• Dateichaos: Eine Datei je Mitarbeiter und Monat, Kopien per E-Mail, unterschiedliche Versionen.
• Stille Fehler: Eine versehentlich überschriebene Formel rechnet einfach falsch weiter.
• Handarbeit für Lohn und Projekte: Stunden je Auftrag und den Export für die Lohnverrechnung (AT) bzw. Lohnabrechnung (DE) müssen Sie selbst zusammentragen.
• Datenschutz: Tabellen mit Arbeitszeiten sind personenbezogene Daten – per E-Mail verschickt, liegen sie schnell an Orten, wo sie nicht hingehören.

Mehr dazu: Zeiterfassung mit Excel ersetzen – so geht der Umstieg

Ab wann sich der Umstieg lohnt

Rechnen Sie selbst: Stunden pro Woche für Einsammeln, Abtippen und Nachfragen × 4,3 × Stundensatz im Büro. Jobilino Basic kostet 5,99 € pro Mitarbeiter und Monat (netto). Bei 15 Mitarbeitern ist das günstiger, sobald das Büro mehr als rund 40 Minuten pro Woche mit Stundenzetteln verbringt (bei 30 € pro Stunde). Mehr dazu: Was kostet Zeiterfassung?

Mit der App stempeln Mitarbeiter direkt am Handy, per NFC-Chip oder am Terminal – auch ohne Netz. Pausen, Überstunden und Monatssummen rechnet das System, und der Export für die Lohnverrechnung ist ein Klick.

14 Tage kostenlos testen – ohne Kreditkarte →